macOS中自动化批量将Word文档导出为PDF

说明

业务需求，需要在手机端（web）显示ppt或者word文档，第一版考虑使用PDF显示，可在手机端使用js直接解析pdf性能糟糕，查看或者翻页不够流畅，立马考虑使用图片来代替PDF。
1.macOS中自动化批量将PPT文档导出为PDF
2.macOS中自动化批量将PDF文档导出为图片

前置条件

电脑上必须安装 Microsoft Word软件

操作步骤

• 打开自动操作，新建『工作流程』
• 将『操作>文件和文件夹>获取指定的访达项目』拖到操作区域，或者直接选择一个Word文件拖动到操作区域。
• 将『操作>实用工具>运行AppleScript』拖到操作区域，复制一下代码

property theList : {"doc", "docx"}
on run {input, parameters}
    set output to {}
    tell application "Microsoft Word" to set theOldDefaultPath to get default file path file path type documents path
    repeat with x in input
        try
            set theDoc to contents of x
            tell application "Finder"
                set theFilePath to container of theDoc as text
                set ext to name extension of theDoc
                if ext is in theList then
                    set theName to name of theDoc
                    copy length of theName to l
                    copy length of ext to exl
                    set n to l - exl - 1
                    copy characters 1 through n of theName as string to theFilename
                    set theFilename to theFilename & ".pdf"
                    tell application "Microsoft Word"
                        set default file path file path type documents path path theFilePath
                        open theDoc
                        set theActiveDoc to the active document
                        save as theActiveDoc file format format PDF file name theFilename
                        copy (POSIX path of (theFilePath & theFilename as string)) to end of output
                        close theActiveDoc
                    end tell
                end if
            end tell
        end try
    end repeat
    tell application "Microsoft Word" to set default file path file path type documents path path theOldDefaultPath
    return output
end run

• 将『操作>文件和文件夹>移动访达项目』拖到操作区域，选择要输出的目录。
• 在『获取指定的访达项目』中选择想要导出为PDF文件的Word文件。点击运行即可。
  

  使用中的问题

1. 脚本问题，每次多个个文件导出时第一个总不能成功导出。